胡杨

@echo off
rem 建立用户并分配权限
rem 格式: creauser 班级名称 班级代称 人数 建立目录的根目录
rem 例: 要建立计算机0210班级用户,人数为50,根目录为d盘的话.
rem 则命令是:creauser 计算机0210 jsj0210 50 d:
 
if "%1"=="" goto error
if "%1"=="/?" goto error
if "%4"=="" goto error
 
echo ====建立班级组
net group %2 /add /comment:"%1"
 
echo ====建立班级组上的用户,并把各用户加到班级组中去
for /L %%i in (1,1,9) do net user %20%%i %20%%i /comment:"%1" /add & net group %2 %20%%i /add
for /L %%i in (10,1,%3) do net user %2%%i %2%%i /comment:"%1" /add & net group %2 %2%%i /add
 
echo ====建立班级目录并分配权限
md %4\%2 & echo y|cacls %4\%2 /t /c /p administrators:f %2:r
rem 建立学生目录01,02,03, ..., 并分配权限
for /L %%i in (1,1,9) do md %4\%2\0%%i & echo y|cacls %4\%2\0%%i /t /c /p %20%%i:c administrators:f
rem 建立学生目录10,12,13, ...
for /L %%i in (10,1,%3) do md %4\%2\%%i & echo y|cacls %4\%2\%%i /t /c /p %2%%i:c administrators:f
 
echo ====共享目录
net share %2=%4\%2
 
goto end
 
:error
echo 格式: creuser 班级名称 班级代称 人数 建立目录的根目录
echo 如: 要建立计算机0210班级用户,人数为50,想把班级目录建在D盘的话
echo 则: creauser 计算机0210 jsj0210 50 d:
 
goto end
 
:end
echo ====成功完成. END

@echo off
rem 删除班级用户及目录
rem 格式: deleuser 班级名称 班级代称 人数 建立目录的根目录
rem 例: 要删除计算机0210班级用户,人数为50,根目录为d盘的话.
rem 则命令是:deleuser 计算机0210 jsj0210 50 d:
 
if "%1"=="" goto error
if "%1"=="/?" goto error
if "%4"=="" goto error
 
echo ====删除班级组上的用户
for /L %%i in (1,1,9) do net user %20%%i /delete
for /L %%i in (10,1,%3) do net user %2%%i /delete
 
echo ====删除班级组
net group %2 /delete
 
echo ====删除班级目录
rd %4\%2 /s /q
rem 下面命令只删除文件不删除目录
rem del %4\%2 /s a /q /f
 
goto end
 
:error
echo 格式: deleuser 班级名称 班级代称 人数 建立目录的根目录
echo 如: 要删除计算机0210班级用户,人数为50,想把班级目录建在D盘的话
echo 则: deleuser 计算机0210 jsj0210 50 d:
 
goto end
 
:end
echo ====成功完成. END